applock-mode-transact-sql.md

description	APPLOCK_MODE (Transact-SQL)
title	APPLOCK_MODE (Transact-SQL) | Microsoft Docs
ms.custom
ms.date	07/24/2017
ms.prod	sql
ms.prod_service	database-engine, sql-database
ms.reviewer
ms.technology	t-sql
ms.topic	reference
f1_keywords	APPLOCK_MODE_TSQL APPLOCK_MODE
dev_langs	TSQL
helpviewer_keywords	locking [SQL Server], applications applications [SQL Server], locks sessions [SQL Server], application locks APPLOCK_MODE function
ms.assetid	e43d4917-77f1-45cc-b231-68ba7fee3385
author	cawrites
ms.author	chadam

APPLOCK_MODE (Transact-SQL)

[!INCLUDE SQL Server SQL Database]

This function returns the lock mode held by the lock owner on a particular application resource. As an application lock function, APPLOCK_MODE operates on the current database. The database is the scope of the application locks.

Transact-SQL Syntax Conventions

Syntax

APPLOCK_MODE( 'database_principal' , 'resource_name' , 'lock_owner' )  

[!INCLUDEsql-server-tsql-previous-offline-documentation]

Arguments

'database_principal'
The user, role, or application role that can be granted permissions to objects in the database. To successfully call the function, the function caller must be a member of database_principal, dbo, or the db_owner fixed database role.

'resource_name'
A lock resource name specified by the client application. The application must ensure a unique resource name. The specified name is hashed internally into a value that the [!INCLUDEssNoVersion] lock manager can internally store. resource_nameis nvarchar(255), with no default. resource_name is binary compared, and is case-sensitive regardless of the collation settings of the current database.

'lock_owner'
The owner of the lock, which is the lock_owner value when the lock was requested. lock_owner is nvarchar(32), and the value can be either Transaction (the default) or Session.

Return types

nvarchar(32)

Return value

Returns the lock mode held by the lock owner on a particular application resource. Lock mode can have any one of these values:

NoLock	Update	*SharedIntentExclusive
IntentShared	IntentExclusive	*UpdateIntentExclusive
Shared	Exclusive

*This lock mode is a combination of other lock modes and sp_getapplock cannot explicitly acquire it.

Function properties

Nondeterministic

Nonindexable

Nonparallelizable

Examples

Two users (User A and User B), with separate sessions, run the following sequence of [!INCLUDEtsql] statements.

User A runs:

USE AdventureWorks2012;  
GO  
BEGIN TRAN;  
DECLARE @result INT;  
EXEC @result=sp_getapplock  
    @DbPrincipal='public',  
    @Resource='Form1',  
    @LockMode='Shared',  
    @LockOwner='Transaction';  
SELECT APPLOCK_MODE('public', 'Form1', 'Transaction');  
GO  

User B then runs:

Use AdventureWorks2012;  
GO  
BEGIN TRAN;  
SELECT APPLOCK_MODE('public', 'Form1', 'Transaction');  
--Result set: NoLock  
  
SELECT APPLOCK_TEST('public', 'Form1', 'Shared', 'Transaction');  
--Result set: 1 (Lock is grantable.)  
  
SELECT APPLOCK_TEST('public', 'Form1', 'Exclusive', 'Transaction');  
--Result set: 0 (Lock is not grantable.)  
GO  

User A then runs:

EXEC sp_releaseapplock @Resource='Form1', @DbPrincipal='public';  
GO  

User B then runs:

SELECT APPLOCK_TEST('public', 'Form1', 'Exclusive', 'Transaction');  
--Result set: '1' (The lock is grantable.)  
GO  

User A and User B then run:

COMMIT TRAN;  
GO  

See also

APPLOCK_TEST (Transact-SQL)
sp_getapplock (Transact-SQL)
sp_releaseapplock (Transact-SQL)